Antidote 11 — Installation multiposte Windows

Installation multiposte Windows / 5 - Déploiement automatisé par GPO / 3 - Installation d’Antidote 11 / Méthode 1 - Installation d’Antidote 11 par ligne de commande

Méthode 1 - Installation d’Antidote 11 par ligne de commande

La procédure d’installation locale par ligne de commande est l’une des méthodes de déploiement par GPO. Elle consiste à :

  1. Entrer dans un compte administrateur.
  2. Télécharger depuis votre Espace client Multiposte les fichiers de type Antidote_11.y_B_n_Windows.exe et GestionnaireMultiposte_Antidote11.exe.
  3. Vous assurer que les conditions sont respectées.
  4. Exécuter l’archive principale, de la forme Antidote_11.y_B_n_Windows.exe, ce qui décompressera sur le bureau un dossier de la forme Antidote_11.y_B_n_Installation contenant les fichiers d’installation.
  5. Créer les fichiers ReseauAntidote.mst et ReseauConnectix.MST à l’aide du Gestionnaire multiposte, qui vous demandera de lui indiquer les fichiers Antidote11.msi et Antidote-Connectix11.msi, voir Annexe A: Gestionnaire multiposte.

  6. Placer tous les fichiers nécessaires sur le serveur (ou un disque accessible), ainsi que toutes les mises à jour MSP, s’il y a lieu (s’il y a des mises à jour publiées plus récentes que vos installateurs). Par exemple, pour une installation bilingue :

    Antidote11.msi
    Antidote11-Module-francais.msi
    Antidote11-English-module.msi
    Antidote-Connectix11.msi
    ReseauAntidote.mst (créé précédemment)
    ReseauConnectix.mst (créé précédemment)
    Il peut y avoir une mise à jour MSP publiée pour chacun des éléments : une pour Antidote 11, une pour Antidote — Connectix 11, une pour le Module Français et une pour le Module Anglais. À cela peut s’ajouter une mise à jour MSP de connecteurs, qui sont les extensions ou modules installés dans les logiciels pris en charge. Une seule mise à jour de connecteurs peut viser plusieurs logiciels. Ce type de mise à jour est publiée entre les mises à jour de l’application Antidote et a pour but d’être publiée plus rapidement qu’une mise à jour complète de l’application, pour s’adapter plus rapidement à l’évolution des différents logiciels pris en charge. Votre mise à jour peut d’ailleurs se limiter à une telle mise à jour.

    Si vous voulez modifier la langue prévue pour les dialogues de l’installateur, pour que ceux-ci soient en français, il faut aussi utiliser les fichiers MST qui s’appliquent et qui se trouvent dans le dossier msi\druide, par exemple : Antidote11-Interface-fr.mst pour l’installateur Antidote 11, Antidote-Connectix11-Interface-fr.mst pour l’installateur Antidote — Connectix 11, Antidote11-English-module-Interface-fr.mst pour l’installateur du Module Anglais et Antidote11-Module-francais-Interface-fr.mst pour l’installateur du Module Français. Voir plus loin comment les ajouter à la ligne de commande.

    Lorsqu’une mise à jour d’Antidote est publiée, l’installateur complet d’Antidote correspondant à la version de cette mise à jour est normalement publié dans les jours suivants. Dès que l’installateur est publié, il apparait dans votre Espace client Multiposte si vous avez souscrit au Programme de maintenance Antidote (PMA). Sinon, il est toujours possible d’installer Antidote avec les installateurs initiaux, accessibles depuis votre Espace client Multiposte, puis d’appliquer les dernières mises à jour : le résultat final est le même.

    Dans la séquence d’installation, il est essentiel que le fichier Antidote11.msi soit lancé en premier : l’installation de l’application Antidote 11 doit être effectuée avant l’installation des modules de langue.

  1. Utiliser GPO pour déployer un script plutôt que les installateurs MSI directement. Ce script déploie les 3 ou 4 MSI dans l’ordre approprié.

    • GPO ne permet pas de garantir l’ordre d’installation, il est nécessaire de réaliser le déploiement à l’aide d’un script d’installation. Pour un exemple de script, voir la section Utilisation de scripts.
    • Dans l’interface de GPO, assigner le script à une machine, et non à un utilisateur.
    • Le script doit être déployé de façon synchrone à l’ouverture du poste. Ainsi, selon votre version de Windows Server, les deux politiques suivantes doivent être activées :
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts synchronously = Enabled
      ET
      Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
      Run logon scripts asynchronously = Disabled

    L’utilisation du gestionnaire multiposte (voir Annexe A: Gestionnaire multiposte) est essentielle pour permettre une installation silencieuse.

Nous fournissons ici, à titre d’exemple, le contenu d’un script qui permet de faire l’installation silencieuse initiale d’Antidote. Veuillez noter la présence de fichiers témoins, ils sont nécessaires afin d’empêcher une installation inutile à chaque exécution du script :

@echo OFF
rem Attention ce fichier est encod‚ en code page DOS-850

echo D‚ploiement d’Antidote 11...

set CHEMIN_SERVEUR=\\SERVEUR\DossierAntidote
set CHEMIN_LOCAL=C:\Program Files (x86)\Druide\Antidote 11
mkdir "%CHEMIN_LOCAL%"

if exist "%CHEMIN_LOCAL%\TemoinDesAnciensAntidote" goto OK_DESANCIENANTIDOTE
rem A6 (Antidote RX)
msiexec /qn /x {A474EA56-5DBD-4181-8230-806A4762EA7F} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA6.txt"
rem A7 (Antidote HD)
msiexec /qn /x {56CDB4FE-895F-4E0D-8BB4-9A8D4310898D} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA7.txt"
rem A8 (Antidote 8)
msiexec /qn /x {09AAAB09-6DBA-4DD9-9865-54597D3FBCA8} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA8.txt"
rem A9 (Antidote 9)
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB6} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA9.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB7} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA9_FR.txt"
msiexec /qn /x {BFA17B4C-70D3-480F-8476-76197F614AB8} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA9_EN.txt"
rem A10 (Antidote 10)
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB1} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB2} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10_FR.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB3} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10_EN.txt"
msiexec /qn /x {134E0741-C569-4E8C-A7FC-7F95B14CAAB4} /l*v "%CHEMIN_LOCAL%\logDesAncienAntidoteA10_CNX.txt"
echo . > "%CHEMIN_LOCAL%\TemoinDesAnciensAntidote"
:OK_DESANCIENANTIDOTE

if exist "%CHEMIN_LOCAL%\TemoinInsAntidote" goto OK_ANTIDOTE
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote11.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauAntidote.mst;%CHEMIN_SERVEUR%\Antidote11-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsAntidote.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsAntidote"
:OK_ANTIDOTE

if exist "%CHEMIN_LOCAL%\TemoinInsModuleFrancais" goto OK_MODULE_FR
if not exist "%CHEMIN_SERVEUR%\Antidote11-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote11-Module-francais.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote11-Module-francais-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsModuleFr.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsModuleFrancais"
:OK_MODULE_FR

if exist "%CHEMIN_LOCAL%\TemoinInsEnglishModule" goto OK_MODULE_EN
if not exist "%CHEMIN_SERVEUR%\Antidote11-English-module.msi" goto OK_MODULE_EN
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote11-English-module.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote11-English-module-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsModuleEn.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsEnglishModule"
:OK_MODULE_EN

if exist "%CHEMIN_LOCAL%\TemoinInsConnectix" goto OK_CONNECTIX
if not exist "%CHEMIN_SERVEUR%\Antidote-Connectix11.msi" goto OK_CONNECTIX
msiexec /qn /i "%CHEMIN_SERVEUR%\Antidote-Connectix11.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauConnectix.mst;%CHEMIN_SERVEUR%\Antidote-Connectix11-Interface-fr.mst" /l*v "%CHEMIN_LOCAL%\logInsConnectix.txt"
echo . > "%CHEMIN_LOCAL%\TemoinInsConnectix"
:OK_CONNECTIX